Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

Over Uitwisselprofiel Zorgkantoren Inkoopondersteuning en beleidsontwikkeling

Publicatiedatum:
01-05-2026
Inwerkingtreding:
01-05-2026
Bekijk bron...

14.3 Wat is het aantal cliënten met een Wlz-indicatie per zorgprofiel VV en leveringsvorm?

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 14.3
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg:<http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13  (?vestiging as ?Indeling)
14  (?zorgprofiel AS ?Zorgprofiel)
15  (SUM(?max_vmb) AS ?Verblijf_met_behandeling)
16  (SUM(?max_vzb) AS ?Verblijf_zonder_behandeling)
17  (SUM(?max_vpt) AS ?VPT)
18  (SUM(?max_mpt) AS ?MPT)
19  (SUM(?max_pgb) AS ?PGB)
20  (SUM(IF((?max_vmb + ?max_vzb + ?max_vpt + ?max_mpt + ?max_pgb) > 0, 1, 0)) AS ?Totaal)
21WHERE {
22    SELECT
23      ?vestiging
24      ?client
25      ?zorgprofiel
26      (MAX(?vmb) AS ?max_vmb)
27      (MAX(?vzb) AS ?max_vzb)
28      (MAX(?vpt) AS ?max_vpt) 
29      (MAX(?mpt) AS ?max_mpt)
30      (MAX(?pgb) AS ?max_pgb)
31    WHERE {
32      # BIND ("2023-01-01"^^xsd:date AS ?peildatum)
33      VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
34
35      # Zorgprocessen binnen peildatum
36      ?zorgproces a onz-zorg:NursingProcess ;
37          onz-g:definedBy ?indicatie ;
38          onz-g:startDatum ?start_zorgproces .
39      OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
40      FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum) || !BOUND(?eind_zorgproces)))
41
42      # Indicatie + cliënt
43      ?indicatie a onz-zorg:WlzIndicatie ;  
44          onz-g:hasPart ?zorgprofiel ;
45          onz-g:hasPart ?lv ;
46          onz-g:isAbout ?client ;
47          onz-g:startDatum ?ind_start .
48
49      # Indicatie filter peildatum 
50      OPTIONAL { ?indicatie onz-g:eindDatum ?ind_eind }
51      FILTER (?ind_start <= ?peildatum && ((?ind_eind >= ?peildatum) || (!BOUND(?ind_eind))))
52	    ?client a onz-g:Human .
53            
54	    {
55        # Per vestiging
56        ?zorgproces onz-g:hasPerdurantLocation ?locatie .
57        ?locatie onz-g:partOf* ?vestiging_uri .
58        ?vestiging_uri a onz-org:Vestiging ;
59            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6;
60            onz-g:identifiedBy ?vest_nr . 
61        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
62        ?pc_gebied 
63            onz-g:identifiedBy ?postcode ;
64            onz-g:partOf+ ?zk_regio .
65        ?zk_regio a onz-org:ZorgkantoorRegio .
66        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
67        ?vest_nr a onz-org:Vestigingsnummer ;
68            onz-g:hasDataValue ?vestiging .
69    }
70    UNION
71    {
72        # Totaal organisatie (inclusief zorgprocessen zonder locatie)
73        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
74    }
75
76      # Van de indicatiebesluiten3 met leveringsvorm5 verblijf8 bepaal of het met of zonder behandeling7 is.
77      OPTIONAL { ?indicatie onz-zorg:heeftIndicatieBehandeling ?behandeling }
78      BIND(IF(BOUND(?behandeling), ?behandeling, "false"^^xsd:boolean) AS ?incl_behandeling)
79
80      ?lv a onz-zorg:Leveringsvorm .
81
82      # Vlaggen per indicatie
83      BIND(IF(?lv = onz-zorg:instelling && ?incl_behandeling,      1, 0) AS ?vmb)
84      BIND(IF(?lv = onz-zorg:instelling && !?incl_behandeling,     1, 0) AS ?vzb)
85      BIND(IF(?lv = onz-zorg:vpt,                                  1, 0) AS ?vpt)
86      BIND(IF(?lv = onz-zorg:mpt,                                  1, 0) AS ?mpt)
87      BIND(IF(?lv = onz-zorg:pgb,                                  1, 0) AS ?pgb)
88    }
89    GROUP BY ?vestiging ?client ?zorgprofiel
90}
91GROUP BY ?vestiging ?zorgprofiel 
92
Terug naar: 14.2 Wat is het aantal cliënten per leveringsvorm met zorgprofiel VV?